// stamdata$(?):=line_text$(:1:)     //   posttype
  // stamdata$(?):=line_text$(2:7)     //   yder‑nummer tilknyttet patient
  // stamdata$(?):=line_text$(8:17)    //   cpr‑nummer
  // stamdata$(?):=line_text$(18:47)   //   efternavn, fornavn(e)
  // stamdata$(?):=line_text$(48:81)   //   gadenavn + nr + evt. sal 
  // stamdata$(?):=line_text$(82:82)   //   navn + adressebeskyttelse
  // stamdata$(?):=line_text$(83:85)   //   patientens bopælkommune
  // stamdata$(?):=line_text$(86:105)  //   ændringstype ("kodet" teksttyper)
  // stamdata$(?):=line_text$(106:113) //   ikrafttrædelsesdato
  // stamdata$(?):=line_text$(114:114) //   reguleringer
  // stamdata$(?):=line_text$(115:115) //   fortegn til reguleringer

  // ‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑‑ //

     stamdata$(1):=line_text$(8:17) //     person‑nummer
     stamdata$(1):=stamdata$(1)(1:6)+"‑"+stamdata$(1)(7:10) // tilpas

     exist_pt#:=get_evt_stamdata#   //     måske findes patienten i systemet !

     ændrings_type$:=line_text$(86:105)
     ændrings_type$:=upper$(ændrings_type$)

       IF "NY TILGÅET" IN ændrings_type$ THEN 
            opret#:=exist_pt#+1 // 1 = opret  2 = opdater
            stamdata$(26):="Ny tilgang"; indsæt_data
            
       ELIF "TILG.FRA LÆGE" IN ændrings_type$ THEN 
            opret#:=exist_pt#+1 // 1 = opret  2 = opdater
            stamdata$(26):="Tilflytter"; indsæt_data
            
       ELIF "TILG.FRA GRUPPE" IN ændrings_type$ THEN 
            opret#:=exist_pt#+1 // 1 = opret  2 = opdater
            stamdata$(26):="Tidl. Gr."+ændrings_type$(17:17); indsæt_data
            
       ELIF "AFG. TIL LÆGE" IN ændrings_type$ THEN 
            IF exist_pt# THEN opret#:=2 // opdater
            stamdata$(26):="Fraflytter"; indsæt_data
            
       ELIF "AFG. TIL GRUPPE 9" IN ændrings_type$ THEN 
            IF exist_pt# THEN opret#:=2 // opdater
            stamdata$(26):="MORS"; indsæt_data
            
       ELIF "AFG. TIL GRUPPE 7" IN ændrings_type$ THEN 
            IF exist_pt# THEN opret#:=2 // opdater
            stamdata$(26):="Flt udland"; indsæt_data
            
       ELIF "AFG. TIL GRUPPE" IN ændrings_type$ THEN 
            IF exist_pt# THEN opret#:=2 // opdater
            stamdata$(26):="Afg.  Gr."+ændrings_type$(17:17); indsæt_data
            stamdata$(10):=ændrings_type$(17:17)
            
       ELSE
            // ikke fortolket
       ENDIF

       FUNC get_evt_stamdata# // undersøger om patienten findes allerede !!
          pak_record; keybuf$:=databuf$(pntr#(0+1,1):pntr#(0+1,2))
          TRAP
            b_get_equal(filnr#(1),databuf$,keybuf$,0)
            udpak_record
            RETURN 1 // ja
          HANDLER
            databuf$:=""
            RETURN 0 // nej
          ENDTRAP
       ENDFUNC get_evt_stamdata#
        
       PROC indsæt_data // evt. ændring af navn og adresse
          stamdata$(3):=line_text$(18:47) // efternavn, fornavn(e)
          strip(stamdata$(3)); komma#:="," IN stamdata$(3) // tilpas " "
          IF komma# THEN 
            stamdata$(3):=stamdata$(3)(1:komma#)+" "+stamdata$(3)(komma#+1:)
          ENDIF
          stamdata$(4):=line_text$(48:81); strip(stamdata$(4)) // gade+nr.
          stamdata$(10):="1"; stamdata$(6):=amt$
       ENDPROC indsæt_data